store config settings

Rippo · 06-21-06, 08:05 AM

What is the best way to store settings for a VB.NET 2005 app on a Axim?
I want to implemt a configuration file like you would use for a web app.

e.g.

<configuration>
<appSettings>

<add key="wsURL" value="http://localhost/vanjob/wsprovanltd.asmx" />
</appSettings>
</configuration>

However you cant use ConfigurationSettings.AppSettings("wsURL") as this is not part of .net CF

Can anyone suggest a good way to store settings?

Rippo · 06-22-06, 04:51 AM

Just in case anyone wants this, I decided to hunt around a bit and found this code which I modified a bit

to call just use:-

Functions.GetConfig("wsURL")

Code:

Imports System.Xml
Imports System.IO

Public Class Functions

    ''' <summary>
    ''' AppPath - Dir where EXE is. Works for PDA's
    ''' </summary>
    ''' <remarks></remarks>
    Public Shared AppPath As String = IO.Path.GetDirectoryName(System.Reflection.Assembly.GetExecutingAssembly().GetName().CodeBase).Replace("file:\", "") & "\"


    Protected Sub New()
    End Sub

    ''' <summary>
    ''' Gets a app config variable
    ''' </summary>
    ''' <param name="settingName"></param>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Shared Function GetConfig(ByVal settingName As String) As String
        Dim configPath As String = AppPath & "LVH.exe.config"
        Dim settings As XmlDocument = New XmlDocument
        Dim sr As System.IO.StreamReader = New System.IO.StreamReader(configPath)
        settings.Load(sr)
        sr.Close()
        For Each node As XmlNode In settings("configuration")("appSettings")
            If String.Compare(settingName, node.Attributes("key").Value) = 0 Then
                Return node.Attributes("value").Value
            End If
        Next
        MessageBox.Show("Cannot find " & settingName & " in the .config file.", "Error", MessageBoxButtons.OK, MessageBoxIcon.Exclamation, MessageBoxDefaultButton.Button1)
        Application.Exit()
        Return Nothing
    End Function

    ''' <summary>
    ''' Saves a app config variable
    ''' </summary>
    ''' <param name="settingName"></param>
    ''' <param name="settingValue"></param>
    ''' <remarks></remarks>
    Public Shared Sub SaveConfig(ByVal settingName As String, ByVal settingValue As String)
        Dim configPath As String = AppPath & "LVH.exe.config"
        Dim settings As XmlDocument = New XmlDocument()
        Dim sr As StreamReader = New System.IO.StreamReader(configPath)
        settings.Load(sr)
        sr.Close()
        For Each node As XmlNode In settings("configuration")("appSettings")
            If String.Compare(settingName, node.Attributes("key").Value) = 0 Then
                node.Attributes("value").Value = settingValue
            End If
        Next
        settings.Save(configPath)
    End Sub

End Class